پروژه | ساخت نرم افزار ویرایشگر apk بنام PDA PLANET APK EDITOR

[M_Javad_Nazari]

چیزهایی که تعریف کردم:

تبدیل عددهای وارد شده برای هیپ سایز به اندازه های استاندارد، ضریب 128
تعریف حالت های فشرده سازی برای حالت فشرده سازی Compression Level

Fastest
Fast
Normal
Maximium
Ultra

هوشمند سازی برنامه به منظور دریافت برنامه های ورودی
افزودن گزینه

 13- Delete apk built

به منظور پاک کردن یا نکردن فایل ساخته ی Apk در فولدر پروجکت ، برای کامپایل مجدد. ( من خودم این مشکل رو در نرم افزارهای موجود دارم و همیشه اونو بصورت دستی پاک میکردم، ولی الان اسکریپتش رو نوشتم که بصورت گزینه میتونید انتخاب کنید که آیا قبل از کامپایل مجدد فایل Apk ساخته شده در فولدر build پاک بشه یا نه (

اضافه کردن توضیحات مربوط به هر گزینه در حین انتخاب اون.
نوشتن خروجی برنامه بصورت لوگ بصورت منظم و طبقه بندی شده. نمونه ی اونو توی پست قبل ببینید.



تا الان نرم افزار میتونه یه فایل رو به راحتی دیکامپایل کنه

[Alireza7991]

من نمیدونم که این چیزی که دوست عزیزمون فرمودند ، کجای ویرایشگر نرم افزار اندرویدی میتونه قرار بگیره؟


چون خبری از دوستمون نیست، پس فعلا بیخیال این قسمتش میشیم.

جوادجان منظور من نوشتن این پروژه برای سیستم های arm هست . مثلا یک apk editor کامل قابل اجرای روی دیوایس های اندرویدی !

[M_Javad_Nazari]

جوادجان منظور من نوشتن این پروژه برای سیستم های arm هست . مثلا یک apk editor کامل قابل اجرای روی دیوایس های اندرویدی !

خیلی عالیه، ولی تو گوشی ابزارهای ویرایشگر نیاز داریم.. کار رو خیلی سخت میکنه.
ولی ایده ی خوبیه.


Sent from my GT-I9300 using pda-planet premium

[Alireza7991]

جواد جان من میتونم اپلت های classpath و java و smali رو برای arm کمپایل کنم . چیز دیگه ای لازم هست؟

[M_Javad_Nazari]

سلام علیرضا جان
برای کامپایل و دیکامپایل اینها نیاز هست. ( توی ویندوز )
apktool
aapt

ولی کلا اصلا ارزش نداره که بخوای وقت خودتو تلف کنی، چون واقعا کسی توی تلفن نمیخواد و نمیتونه apk رو ویرایش کنه، چون نرم افزارهای ویرایشگرش خیلی محدود هست.

به نظر من بهتره که وقتت رو بذاری رو پروژه ی اصلی.

[Biftor]

جواد جان من میتونم اپلت های classpath و java و smali رو برای arm کمپایل کنم . چیز دیگه ای لازم هست؟

سلام علی رضا جان
امیدوارم خوب باشی و روز به روز به موفقیت هات اضافه بشه...
کمک بیش پیگیر کارهات هستم که خیلی خوب و عالیه!
اگر میتونید اینکار رو انجام بدید که بتونیم apk یا یه فایل classes.dex رو کامپایل و دیکامپایل کنیم تو گوشی خیلی خوب میشه
من به شخصه خیلی بهش نیاز دارم...
نمیدونم یادت هست یا نه!!! خودت هم خیلی نیازش داشتی!
اگه کمکی بود بگو اگه ازدستم بر بیاد هستم!

موفق باشید

Sent from my GT-I9100 using pda-planet premium

[M_Javad_Nazari]

چیزهایی که تا الان نوشتم، فعلا دارم یه روشی برای زیپ الاین کردن میگردم، نمیدونم چرا انجامش نمیده، خیلی خسته ام، باید یکی به یکی چک کنم، ببینم کجا مشکل دارم.

@ECHO off
setlocal enabledelayedexpansion
REM : Config Color
COLOR 0A
REM : Config Window Size
mode con:cols=150 lines=42
REM :: Strtup Screen
echo.
echo.
echo           PDA PLANET APK EDITOR  
TIMEOUT 1 > nul
echo                 AMESTRIS TEAM 2013
echo.
TIMEOUT 1 > nul
echo                               CREATED  BY: 
TIMEOUT 1 > nul
echo                                           Mohamad Javad Nazari  
echo.
TIMEOUT 1 > nul
echo Loading.... please wait.
TIMEOUT 2 > nul
CLS
ECHO Setting Default Values,,
cd "%~dp0"
:startup
set mte=%~dp0tools\mtee.exe
set logfile=%~dp0\Logfile.xml
set sapp=None
set cprsrtio=5
set heapsize=512
set cprtxt=Normal
SET dltapk=No
set dltapkbltst=1
ECHO======================================================================================================== >>%logfile%
ECHO====   PDA-PLANET APK EDITOR   ========================================================================= >>%logfile%
ECHO==============================   %time%  =========  %date% >>%logfile%
ECHO ===== START ======>>%logfile%
ECHO. >>%logfile%
:main
CLS
cd "%~dp0"
set menu=AMESTRIS
!! ######################## MAIN SCRIPT
REM :: HEADER #######################################################
echo                 PDA PLANET APK EDITOR                             WWW.PDA-PLANET.COM/FORUM                                          aLpha 2.0                  
ECHO ------------------------------------------------------------------------------------------------------------------------------------------------------
echo         MMMMMMMM      MMMMMMMMMM   MMMMMM   MMMMMM        MMMMMMMMMW    MMMMMMMMMMM       MMMMMM   MMMMMMMMMMMMMM    MMMMMMMMMM      MMMMMMMMMMMM 
echo        MMMMMMMMMM     DDMMM   MMM  MMMMDD  MMMMtt         MMMM           MMMMM   MMMM     MMMMMM   WWWWMMMMMMWWWW  MMMMMM  MMMMMM    MMMMM   MMMMM
echo        MMMM  MMMM     DDMMM   MMM  MMMMM   MMMM           MMMM           MMMMM    MMMM    MMMMMM       MMMMMM      MMMMMM  MMMMMM    MMMMM   MMMMM
echo       MMMMM  MMMMW    DDMMMMMMMM   MMMMMMMMMMDD           MMMMMMMWWW     MMMMM    MMMM    MMMMMM       MMMMMM      MMMMMM  MMMMMM    MMMMMMMMMMMM 
echo      MMMMMMWWMMMMMM   DDMMM        MMMMD   MMMM           MMMM           MMMMM    MMMM    MMMMMM       MMMMMM      MMMMMM  MMMMMM    MMMMM   MMMMM
echo     MMMMMMM  MMMMWW   MMMMk        MMMMDD   MMMMDD        MMMMMMWWWW     MMMMM   MMMM     MMMMMM       MMMMMM      MMMMMM  MMMMMM    MMMMM     MMMM
echo    WMMMMMM    MMMMMMW MMMMDD       MMMMMM    MMMMMM       MMMMMMMMMMM   MMMMMMMMMMM       MMMMMM       MMMMMM        MMMMMMMMMM      MMMMM     MMMM
ECHO ______________________________________________________________________________________________________________________________________________________
REM :: MENUS ##########################

!! MAIN SCRIPT --------------

ECHO.
ECHO.
IF %sapp%==None (ECHO                                                You did't select any file, please select apk file) else (ECHO                                                Selected APK : %sapp%)
ECHO.
ECHO _______________________________________________________                                                     _________________________________________
ECHO                                                        ^|                                                   ^| 
ECHO 1- Select APK file                                     ^|                                                   ^|  11- Compression Level = %cprtxt%
ECHO _____________________                                  ^|                                                   ^|
ECHO                    ____  2 - Decompile                 ^|                                                   ^|  12- Heap Size = %heapsize% MB
ECHO                                                        ^|                                                   ^|  
ECHO                    ____  3 - Compile                   ^|                                                   ^|  13- Delete Built APK = %dltapk%
ECHO                                                        ^|                                                   ^| 
ECHO                    ____  4 - Sign Compiled APK         ^|                                                   ^|_________________________________________
ECHO                          40- Sign Selected APK         ^|
ECHO                                                        ^|
ECHO                    ____  5 - ZipAlign Compiled APK     ^|
ECHO                          50- ZipAlign Selected APK     ^|
ECHO                         _______________________________^|
ECHO.
ECHO.
ECHO 00 - Exit PDA-PLANET Apk Editor
ECHO.
ECHO.
ECHO.
ECHO.
ECHO.
ECHO __________________________________________
REM : Enter Number To Decision
SET /P menu=Please make your decision:
IF %menu%==1 (goto slctapk)
IF %menu%==2 (goto dec)
IF %menu%==3 (goto cmpl)
IF %menu%==4 (goto sgnng)
IF %menu%==5 (goto zipa)
IF %menu%==50 (goto zipaslc)
IF %menu%==40 (goto sgnngslc)
IF %menu%==11 (goto compressratio)
IF %menu%==12 (goto heapsize)
IF %menu%==13 (goto dltapkblt)
IF %menu%==00 (goto quit)



REM : Input APK File ## Option 1
:slctapk
CLS
ECHO.
ECHO.
set /A count=00
FOR %%F IN (apk-input/*.apk) DO (
set /A count+=01
set a!count!=%%F
ECHO ^ !count!  = %%F  
ECho.
)
ECHO.
Echo  00 = Back to main menu
ECHO.
ECHO.
ECHO ===================================================
ECHO Select file with related number, input number!
set /P INPUT=Enter It's Number: %=%
set sapp=!a%INPUT%!
set jar=0
set ext=jar
IF "!sapp:%ext%=!" NEQ "%sapp%" set jar=1
IF /I %INPUT% GTR !count! (goto noapp)
IF /I %INPUT%==00 (goto noapperr)
IF /I %INPUT% LSS 1 (goto noapp)
goto main

REM ##### Set Compression Ratio  ### START
:compressratio
ECHO.
ECHO Choose a number between 0 to 9.
ECHO.
ECHO 0= No Compression 
ECHO 9= Ultra Compression
ECHO.
ECHO The Deafult Value is 5 [Normal Compression]
ECHO.
set /P INPUT=Enter Compression Level (0-9) : %=%
ECHO.
set cprsrtio=%INPUT%
IF /I %INPUT% GTR 9 (goto wrongcpr)
IF /I %INPUT% LSS 0 (goto wrongcpr)
CLS
REM ##### Set Compression Ratio  ### END
:cprtxtm
IF %cprsrtio%==0 (SET cprtxt=Store)
IF /I %cprsrtio% GTR 0 (SET cprtxt=Fastest)
IF /I %cprsrtio% GTR 2 (SET cprtxt=Fast)
IF /I %cprsrtio% GTR 4 (SET cprtxt=Normal)
IF /I %cprsrtio% GTR 6 (SET cprtxt=Maximium)
IF /I %cprsrtio% GTR 8 (SET cprtxt=Ultra)
REM ##### Compression Size Converting.. ### START
goto main
:wrongcpr
ECHO.
ECHO You entered wrong number, please enter from [0 ~ 9], please try it again..
ECHO.
goto compressratio


REM ##### Set HEAP SIZE ### START
:heapsize
set /P INPUT=Enter max size for java heap space in megabytes (eg 512) : %=%
set heapsize=%INPUT%
IF /I %INPUT% LSS 512 (SET heapsize=512)
IF /I %INPUT% GTR 512 (SET heapsize=768)
IF /I %INPUT% GTR 768 (SET heapsize=1024)
IF /I %INPUT% GTR 1024 (SET heapsize=1536)
IF /I %INPUT% GTR 1792 (SET heapsize=1792)
IF /I %INPUT% GTR 2048 (SET heapsize=2048)
CLS
goto main
REM ##### Set HEAP SIZE ### END

:noapp
ECHO.
ECHO You entered not valid number, please enter correct number
set sapp=None
TIMEOUT 10
goto slctapk

:noapperr
set sapp=None
goto main

REM ## DECOMPILING PROCCES ##
:dec
IF %sapp%==None (ECHO You didn't select any apk, please select apk at first & TIMEOUT 5& goto main)
cd %~dp0\tools
REM ## RMOVING PREVIUS CREATED APK FILES IF EXISTED.
IF EXIST "../apk-input/unsigned%sapp%" (del /Q "../apk-input\unsigned%sapp%")
IF EXIST "../sapp/signed%sapp%" (del /Q "../apk-input\signed%sapp%")
REM ## RMOVING PREVIUS DATA IF EXISTED.
IF EXIST "../projects/%sapp%" (rmdir /S /Q "../projects/%sapp%")
ECHO *****  Decompiling %sapp%  ***** >>%logfile%
ECHO Decompiling %sapp% , please wait for process....
java -Xmx%heapsize%m -jar apktool.jar d ../apk-input/%sapp% ../projects/%sapp% 2>>%logfile%
ECHO ***************************** >>%logfile%
IF errorlevel 1 (
ECHO.
ECHO "Error : Decompiling failed!" >>%logfile%
ECHO "Error : Decompiling failed! please check the log file"
TIMEOUT 5
)
goto main

:cmpl
cd %~dp0tools
IF NOT EXIST "%~dp0\projects\%sapp%" GOTO ntdcmpled
IF /I %dltapkbltst%==1 (rmdir /S /Q "%~dp0projects/%sapp%/build/apk")
IF EXIST "%~dp0\apk-input\unsigned%sapp%" (del /Q "%~dp0\apk-input\unsigned%sapp%")
ECHO *****  Compiling %sapp%  ***** >> %logfile%
ECHO.
ECHO   Compiling %sapp% , Please wait...
java -Xmx%heapsize%m -jar apktool.jar b "%~dp0projects/%sapp%" "%~dp0\apk-input\unsigned%sapp%" 2>> %logfile%
ECHO ********************************************** >> %logfile%
REM : If compiling get failed!
IF errorlevel 1 (
ECHO.
ECHO "ERROR : Compiling is failed!" >> %logfile%
ECHO "Error : Compiling failed! please check the log file"
TIMEOUT 5
goto main
)
REM : Seems working or not ?
REM : Extarct META-INF Folder from ORIGINAL APK
7za x -o"%~dp0/projects/temp" "../apk-input/%sapp%" META-INF -r
REM : Copy Original Signature to Created APK File
CLS
7za a -tzip "%~dp0/apk-input/unsigned%sapp%" "../projects/temp/*" -mx%cprsrtio% -r
REM : Remove Temporary files.
rmdir /S /Q "%~dp0/projects/temp"
REM : Its System Or Not?
ECHO.
ECHO Enter "0" for accept or hit any key to skip.
CLS
set /P INPUT=Is this SYSTEM APK ? : %=%
IF /I %INPUT%==0 (goto orgsign)
IF NOT %INPUT%==""  (ECHO. & ECHO You entered wrong value, please try it again & echo. & ECHO you must enter "0" or "1" & Echo hit any key to return & TIMEOUT 10 >nul & goto dltapkblt)
goto main

:orgsign
rmdir /S /Q "%~dp0/keep"
CLS
ECHO.
ECHO.
echo   SYSTEM APK MODIFICATION WINDOW
ECHO   ______________________________
CD %~dp0/tools
REM : Extract Original APK file
7za x -o"%~dp0/keep" "%~dp0/apk-input/%sapp%" >nul
REM : Extract Unsigned APK File
REM :: 7za x -o"../projects/temp" "../apk-input/unsigned%sapp%" -r
cd %~dp0/keep
start .
ECHO.
ECHO    From opened window, please delete files that you were modified!!
ECHO.
ECHO    After you did it, please close keep folder and hit any key.
pause >nul
cd %~dp0tools
REM : Zipping Remained Files into Unsigned APK folder
ECHO    Creating APK File, please wait..
7za a -tzip "%~dp0apk-input/unsigned%sapp%" "%~dp0keep/*" -mx%cprsrtio%
pause
rmdir /S /Q "%~dp0/keep"
goto main
REM : Goto MAIN

REM : Create Sign for an APK
:sgnng
ECHO *****  Signing unsigned%sapp%  ***** >> %logfile%
ECHO Signing unsigned%sapp%
cd %~dp0tools
java -Xmx%heapsize%m -jar signapk.jar -w testkey.x509.pem testkey.pk8 %~dp0/apk-input/unsigned%sapp% %~dp0/apk-input/signed%sapp%
IF errorlevel 1 (
ECHO "ERROR : Signing get failed!" >> %logfile%
ECHO "Error : Signing get failed! please check the log file"
TIMEOUT 10
)
ECHO ********************************************** >> %logfile%
DEL /Q "%~dp0/apk-input/unsigned%sapp%"
goto main

:sgnngslc
ECHO *****  Signing %sapp%  ***** >> %logfile%
ECHO Signing %sapp%
cd %~dp0tools
java -Xmx%heapsize%m -jar signapk.jar -w testkey.x509.pem testkey.pk8 %~dp0/apk-input/%sapp% %~dp0/apk-input/signed%sapp%
IF errorlevel 1 (
ECHO "ERROR : Signing get failed!" >> %logfile%
ECHO "Error : Signing get failed! please check the log file"
TIMEOUT 10
)
ECHO ********************************************** >> %logfile%
DEL /Q "%~dp0/apk-input/unsigned%sapp%"
goto main

###############################################!! ZIP ALIGNING !!
REM : Zipaligning 
:zipa
cd %~dp0tools
IF EXIST "%~dp0\apk-input\signed%sapp%" (zipalign -f 4 "%~dp0\apk-input\signed%sapp%" "%~dp0\apk-input\aligned_signed%sapp%")
IF EXIST "%~dp0\apk-input\unsigned%sapp%" (zipalign -f 4 "%~dp0\apk-input\unsigned%sapp%" "%~dp0\apk-input\aligned_unsigned%sapp%")
IF errorlevel 1 (
ECHO "ERROR : Signing get failed!" >> %logfile%
ECHO "Error : Signing get failed! please check the log file"
TIMEOUT 10
)
DEL /Q "%~dp0\apk-input\signed%sapp%"
DEL /Q "%~dp0\apk-input\unsigned%sapp%"
goto main
:zipaslc
cd %~dp0tools
IF EXIST "%~dp0\apk-input\%sapp%" (zipalign -f 4 "%~dp0\apk-input\%sapp%" "%~dp0\apk-input\aligned_%sapp%")
IF errorlevel 1 (
ECHO "ERROR : Signing get failed!" >> %logfile%
ECHO "Error : Signing get failed! please check the log file"
TIMEOUT 10
)
goto main
##################################################################
:ntdcmpled
ECHO.
ECHO You must decompile this apk at first..
ECHO Return to main menu..
TIMEOUT 3
goto main

:dltapkblt
CLS
echo.
echo.
echo   DELETE APK FILE FROM PROJECT FOLDER BEFORE COMPILING AGAIN A PROJECT ?
echo   ______________________________________________________________________
echo.
echo.
echo        When you enable this option , script will delete built apk files from prevoius compiling procces on project folder.
echo        Delete previous created apk file from project folder? 
echo.
echo.
echo        Current Value = %dltapk% 
echo.
echo                                      0 = NO
echo                                      1 = YES  
echo.
echo        Please make your desicion 
echo        ____________________________________
set /P INPUT=^|                                    : %=%
set dltapkbltst=%INPUT%
IF /I %INPUT%==0 (SET dltapk=No & goto main)
IF /I %INPUT%==1 (SET dltapk=Yes & goto main)
IF NOT %INPUT%==""  (ECHO. & ECHO You entered wrong value, please try it again & echo. & ECHO you must enter "0" or "1" & Echo hit any key to return & TIMEOUT 10 >nul & goto dltapkblt)
CLS
goto main
REM : Exit Section
:quit
CLS
echo. >>%logfile%
ECHO =====  END  ====== >>%logfile%
ECHO ======================================================================================================= >>%logfile%
ECHO ******************************************************************************************************* >>%logfile%
echo. >>%logfile%
echo.
echo.
echo.
Echo Hit any key for exit PDA-PLANET APK EDITOR.
pause > nul
exit 

بعد از اینکه این پروژه هم تموم شد، یه ویرایشگر اسمالی میسازم، چون حس میکنم به اونم نیاز هست.

[masoud]

سلام جواد جان
کارت درسته عزیز دل
واقعا خسته نباشی
منتظر کار هستم
شک ندارم مثل کارای دیگه ات خوب و عالیه
موفق باشی

Sent from my GT-I9000 using pda-planet premium

[M_Javad_Nazari]

درود فراوان به همگی

نسخه ی اولیه این برنامه رو به زودی توی تاپیک جدیدی منتشر میکنم.

قابلیت های جدیدی که اضافش کردم، اینه که فریمورک ها رو براحتی براتون نصب میکنه و نیازی به نصب دستی اونا نیست.

[Alireza7991]

سلام

من نسخه ی ارم ( اندروید ) رو کمپایل کردم و الان احتمالا یک APK Editor کامل تحت ارم داشته باشیم فقط اگه امکانش هست یکی سورس یک فایل apk کوچک ( زیر ۱ مگ ) رو به من بده تا تست کنم که کمپایل میشه یا خیر ؛